#
#  make misc plots
#
# vplot1        slew velocity
vplot1 0 da DAT.vplot
	expand 1.1
	read V 1 read siga 2 read sig 3
	erase
	limits 0 1.6 0.0 0.07  box
	ptype 4 0 points V sig
	ptype 4 3 points V siga
	xlabel OTF Slew Speed [deg/s]
	ylabel Residuals [K]: Solid=Noise+ATM, Empty=Noise only
	toplabel 12 arcmin source, 300 GHz, PWV=1, \sigma_{\phi}=1 deg
# vplot2   slew velocity, version 2
vplot2 0 da DAT.vplot2
	expand 1.1
	read V 1 read siga 2 read sig 3
	erase
	limits 0 1.6 0.0 0.07  box
	ptype 4 0 points V sig
	ptype 4 3 points V siga
	xlabel OTF Slew Speed [deg/s]
	ylabel Residuals [K]: Solid=Noise+ATM, Empty=Noise only
	toplabel 1.2 arcmin source, 300 GHz, PWV=1, \sigma_{\phi}=1 deg
# splot   Makes "size" plot
splot 0 da AAA.size
	expand 1.1
	read I 1 read SIZE 2 read SIG 3 read SIGA 4 read VSLEW 5 read TINT 6
	SET SIZE = SIZE / 0.00207
	SET SIGA2 = SIGA / (SIZE)**(0.5)
	limits 0 53 0 0.017
	erase box
	ptype 4 0 points SIZE SIGA
	ptype 4 3 points SIZE SIGA2
	xlabel Source Size (in 7.5 arcsec Beams)
	ylabel Residuals [K]: Solid = Resid/sqrt(N_{beams})
	toplabel OTF Noise+ATM Residuals with Size, 345 GHz, PWV=0.822mm, \sigma_{\phi}=1.75 deg 
# eplot     Makes elevation plot
eplot 0 da DAT.el2
	expand 1.1
	read EL 1 read V1 2 read V2 6
	read DT1 3 read DT2 7
	read SIGA1 4 read SIGA2 8
	read SIG1 5 read SIG2 9
	limits 10 80 0 0.025
  	erase
	box
	ptype 4 0 points EL SIG1
	ptype 3 0 points EL SIG2
	ptype 4 3 points EL SIGA1
	ptype 3 3 points EL SIGA2
	xlabel Elevation Angle
	ylabel On-Source Residual [K]
	toplabel 300 GHz, 3 arcmin, OTF#
# gplot1 0     gain plot for 230 GHz
gplot1 0 da GAIN1.DAT
	read GERR 2 read SIG 4 read SLEW 5 read DT 6
	SET LGERR = LG(GERR)
	SET NOISESIG = (0 * SIG + 0.0047)
	SET ATMOSIG = (0 * SIG + 0.0054)
	SET THEORY = GERR * 108.20   #  tsys
	ticksize -1 0 0 0
	erase
	limits LGERR 0 0.090
	box expand 1.1
	ptype 4 3 ltype 0 points LGERR SIG  connect LGERR SIG
	ptype 4 2 ltype 1 points LGERR ATMOSIG  connect LGERR ATMOSIG
	ptype 4 0 ltype 2 points LGERR NOISESIG  connect LGERR NOISESIG
	ptype 3 3 ltype 3 points LGERR THEORY    connect LGERR THEORY
	SET XX = {-4.9 -4.57}
	SET YY = {0.078 0.078}
	ptype 3 3 ltype 3 points XX YY connect XX YY
	relocate -4.52 0.077 label \delta G/G * T_{sys}
	SET YY = {0.068 0.068}
	ptype 4 3 ltype 0 points XX YY connect XX YY
	relocate -4.52 0.067 label Thermal + Atmos + Gain Flucs
	SET YY = {0.058 0.058}
	ptype 4 2 ltype 1 points XX YY connect XX YY
	relocate -4.52 0.057 label Thermal + Atmos
	SET YY = {0.048 0.048} 
	ptype 4 0 ltype 2 points XX YY connect XX YY
	relocate  -4.52 0.047  label Thermal Noise
	xlabel \delta G / G
	ylabel On-Source Residuals [K]	
	toplabel Effect of Gain Flucs: 230 GHz, 3 arcminute, OTF, 60 deg el
# gplot2 0     gain plot for 680 GHz
gplot2 0 da GAIN2.DAT
	read GERR 2 read SIG 4 read SLEW 5 read DT 6
	SET LGERR = LG(GERR)
	SET NOISESIG = (0 * SIG + 0.053)
	SET ATMOSIG = (0 * SIG + 0.061)
	ticksize -1 0 0 0
	erase
	limits LGERR 0 0.65
	box ptype 4 3 expand 1.1
	ptype 4 3 ltype 0 points LGERR SIG connect LGERR SIG
	ptype 4 2 ltype 1 points LGERR ATMOSIG  connect LGERR ATMOSIG
	ptype 4 0 ltype 2 points LGERR NOISESIG  connect LGERR NOISESIG
	SET XX = {-4.9 -4.57}
	SET YY = {0.58 0.58}
	ptype 4 3 ltype 0 points XX YY connect XX YY
	relocate -4.52 0.57 label Thermal + Atmos + Gain Flucs
	SET YY = {0.50 0.50}
	ptype 4 2 ltype 1 points XX YY connect XX YY
	relocate -4.52 0.49 label Thermal + Atmos
	SET YY = {0.42 0.42} 
	ptype 4 0 ltype 2 points XX YY connect XX YY
	relocate  -4.52 0.41  label Thermal Noise
	xlabel \delta G / G
	xlabel \delta G / G
	ylabel On-Source Residuals [K]	
	toplabel Effect of Gain Flucs: 680 GHz, 3 arcminute, OTF, 60 deg el
#  ave    averages AAA.integrate2
ave 0	da AAA.integrate2
	read COND 1 read BAND 2 read SIG 3 read SIGA 4
	read VSLEW 5 read DT 6
	do II=1,10 {
	  SET SIG_ = SIG IF (BAND == ($II) && COND == 0)
	  SET SIGA_ = SIGA IF (BAND == ($II) && COND == 0)
	  SET VSLEW_ = VSLEW IF (BAND == ($II) && COND == 0)
	  SET DT_ = DT IF (BAND == ($II) && COND == 0)
	  stats SIG_ a1 r k 
	  stats SIGA_ a2 r k 
	  stats VSLEW_ a3 r k 
	  stats DT_ a4 r k 
	  echo A $II $a1 $a2 $a3 $a4
	  SET SIG_ = SIG IF (BAND == ($II) && COND == 1)
	  SET SIGA_ = SIGA IF (BAND == ($II) && COND == 1)
	  SET VSLEW_ = VSLEW IF (BAND == ($II) && COND == 1)
	  SET DT_ = DT IF (BAND == ($II) && COND == 1)
	  stats SIG_ a1 r k 
	  stats SIGA_ a2 r k 
	  stats VSLEW_ a3 r k 
	  stats DT_ a4 r k 
	  echo B $II $a1 $a2 $a3 $a4
        }